From dbb7ed14e8562439238eec70b202c50f172e3def Mon Sep 17 00:00:00 2001
From: Hennadii Stepanov <32963518+hebasto@users.noreply.github.com>
Date: Sun, 30 Jun 2024 11:02:05 +0100
Subject: [PATCH] cmake: Add `ccache` support

---
 CMakeLists.txt     |  9 +++++++++
 cmake/ccache.cmake | 36 ++++++++++++++++++++++++++++++++++++
 2 files changed, 45 insertions(+)
 create mode 100644 cmake/ccache.cmake

diff --git a/CMakeLists.txt b/CMakeLists.txt
index 0edb4931c51..f76e61e5b84 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -61,6 +61,12 @@ set(CMAKE_CXX_EXTENSIONS OFF)
 
 list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake/module)
 
+#=============================
+# Configurable options
+#=============================
+# When adding a new option, end the <help_text> with a full stop for consistency.
+option(WITH_CCACHE "Attempt to use ccache for compiling." ON)
+
 set(configure_warnings)
 
 include(CheckPIESupported)
@@ -184,6 +190,8 @@ target_link_libraries(core_interface INTERFACE
 
 include(cmake/introspection.cmake)
 
+include(cmake/ccache.cmake)
+
 # Don't allow extended (non-ASCII) symbols in identifiers. This is easier for code review.
 try_append_cxx_flags("-fno-extended-identifiers" TARGET core_interface SKIP_LINK)
 
@@ -209,6 +217,7 @@ message("=================")
 message("C++ compiler .......................... ${CMAKE_CXX_COMPILER_ID} ${CMAKE_CXX_COMPILER_VERSION}, ${CMAKE_CXX_COMPILER}")
 include(FlagsSummary)
 flags_summary()
+message("Use ccache for compiling .............. ${WITH_CCACHE}")
 message("\n")
 if(configure_warnings)
     message("  ******\n")
diff --git a/cmake/ccache.cmake b/cmake/ccache.cmake
new file mode 100644
index 00000000000..099aa66411f
--- /dev/null
+++ b/cmake/ccache.cmake
@@ -0,0 +1,36 @@
+# Copyright (c) 2023-present The Bitcoin Core developers
+# Distributed under the MIT software license, see the accompanying
+# file COPYING or https://opensource.org/license/mit/.
+
+if(NOT MSVC)
+  find_program(CCACHE_EXECUTABLE ccache)
+  if(CCACHE_EXECUTABLE)
+    execute_process(
+      COMMAND readlink -f ${CMAKE_CXX_COMPILER}
+      OUTPUT_VARIABLE compiler_resolved_link
+      ERROR_QUIET
+      OUTPUT_STRIP_TRAILING_WHITESPACE
+    )
+    if(CCACHE_EXECUTABLE STREQUAL compiler_resolved_link AND NOT WITH_CCACHE)
+      list(APPEND configure_warnings
+        "Disabling ccache was attempted using -DWITH_CCACHE=${WITH_CCACHE}, but ccache masquerades as the compiler."
+      )
+      set(WITH_CCACHE ON)
+    elseif(WITH_CCACHE)
+      list(APPEND CMAKE_C_COMPILER_LAUNCHER ${CCACHE_EXECUTABLE})
+      list(APPEND CMAKE_CXX_COMPILER_LAUNCHER ${CCACHE_EXECUTABLE})
+    endif()
+  else()
+    set(WITH_CCACHE OFF)
+  endif()
+  if(WITH_CCACHE)
+    try_append_cxx_flags("-fdebug-prefix-map=A=B" TARGET core_interface SKIP_LINK
+      IF_CHECK_PASSED "-fdebug-prefix-map=${PROJECT_SOURCE_DIR}=."
+    )
+    try_append_cxx_flags("-fmacro-prefix-map=A=B" TARGET core_interface SKIP_LINK
+      IF_CHECK_PASSED "-fmacro-prefix-map=${PROJECT_SOURCE_DIR}=."
+    )
+  endif()
+endif()
+
+mark_as_advanced(CCACHE_EXECUTABLE)