build: Minimize I/O operations in `GenerateHeaderFrom{Json,Raw}.cmake`

cmake/script/GenerateHeaderFromJson.cmake

@@ -5,22 +5,24 @@
 file(READ ${JSON_SOURCE_PATH} hex_content HEX)
 string(REGEX MATCHALL "([A-Za-z0-9][A-Za-z0-9])" bytes "${hex_content}")
 
-file(WRITE ${HEADER_PATH} "#include <string_view>\n")
-file(APPEND ${HEADER_PATH} "namespace json_tests{\n")
+set(header_content "#include <string_view>\n")
+string(APPEND header_content "namespace json_tests{\n")
 get_filename_component(json_source_basename ${JSON_SOURCE_PATH} NAME_WE)
-file(APPEND ${HEADER_PATH} "inline constexpr char detail_${json_source_basename}_bytes[]{\n")
+string(APPEND header_content "inline constexpr char detail_${json_source_basename}_bytes[]{\n")
 
 set(i 0)
 foreach(byte ${bytes})
   math(EXPR i "${i} + 1")
-  math(EXPR remainder "${i} % 8")
-  if(remainder EQUAL 0)
-    file(APPEND ${HEADER_PATH} "0x${byte},\n")
+  if(i EQUAL 8)
+    set(i 0)
+    string(APPEND header_content "0x${byte},\n")
   else()
-    file(APPEND ${HEADER_PATH} "0x${byte}, ")
+    string(APPEND header_content "0x${byte}, ")
   endif()
 endforeach()
 
-file(APPEND ${HEADER_PATH} "\n};\n")
-file(APPEND ${HEADER_PATH} "inline constexpr std::string_view ${json_source_basename}{std::begin(detail_${json_source_basename}_bytes), std::end(detail_${json_source_basename}_bytes)};")
-file(APPEND ${HEADER_PATH} "\n}")
+string(APPEND header_content "\n};\n")
+string(APPEND header_content "inline constexpr std::string_view ${json_source_basename}{std::begin(detail_${json_source_basename}_bytes), std::end(detail_${json_source_basename}_bytes)};")
+string(APPEND header_content "\n}")
+
+file(WRITE ${HEADER_PATH} "${header_content}")

cmake/script/GenerateHeaderFromRaw.cmake

@@ -5,23 +5,25 @@
 file(READ ${RAW_SOURCE_PATH} hex_content HEX)
 string(REGEX MATCHALL "([A-Za-z0-9][A-Za-z0-9])" bytes "${hex_content}")
 
-file(WRITE ${HEADER_PATH} "#include <cstddef>\n")
-file(APPEND ${HEADER_PATH} "#include <span>\n")
-file(APPEND ${HEADER_PATH} "namespace ${RAW_NAMESPACE} {\n")
+set(header_content "#include <cstddef>\n")
+string(APPEND header_content "#include <span>\n")
+string(APPEND header_content "namespace ${RAW_NAMESPACE} {\n")
 get_filename_component(raw_source_basename ${RAW_SOURCE_PATH} NAME_WE)
-file(APPEND ${HEADER_PATH} "inline constexpr std::byte detail_${raw_source_basename}_raw[]{\n")
+string(APPEND header_content "inline constexpr std::byte detail_${raw_source_basename}_raw[]{\n")
 
 set(i 0)
 foreach(byte ${bytes})
   math(EXPR i "${i} + 1")
-  math(EXPR remainder "${i} % 8")
-  if(remainder EQUAL 0)
-    file(APPEND ${HEADER_PATH} "std::byte{0x${byte}},\n")
+  if(i EQUAL 8)
+    set(i 0)
+    string(APPEND header_content "std::byte{0x${byte}},\n")
   else()
-    file(APPEND ${HEADER_PATH} "std::byte{0x${byte}}, ")
+    string(APPEND header_content "std::byte{0x${byte}}, ")
   endif()
 endforeach()
 
-file(APPEND ${HEADER_PATH} "\n};\n")
-file(APPEND ${HEADER_PATH} "inline constexpr std::span ${raw_source_basename}{detail_${raw_source_basename}_raw};\n")
-file(APPEND ${HEADER_PATH} "}")
+string(APPEND header_content "\n};\n")
+string(APPEND header_content "inline constexpr std::span ${raw_source_basename}{detail_${raw_source_basename}_raw};\n")
+string(APPEND header_content "}")
+
+file(WRITE ${HEADER_PATH} "${header_content}")