From a8a2e364acf55bbe18404ab21f852d52257bcb6d Mon Sep 17 00:00:00 2001
From: Hennadii Stepanov <32963518+hebasto@users.noreply.github.com>
Date: Tue, 6 Aug 2024 18:14:37 +0100
Subject: [PATCH] cmake: Add Python-based tests

---
 CMakeLists.txt                 | 13 +++++++++
 cmake/tests.cmake              | 15 +++++++++++
 test/CMakeLists.txt            | 48 ++++++++++++++++++++++++++++++++++
 test/functional/test_runner.py |  2 +-
 4 files changed, 77 insertions(+), 1 deletion(-)
 create mode 100644 cmake/tests.cmake
 create mode 100644 test/CMakeLists.txt

diff --git a/CMakeLists.txt b/CMakeLists.txt
index 1f684c1515e..646c5a86aab 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -351,6 +351,15 @@ try_append_cxx_flags("-fno-extended-identifiers" TARGET core_interface SKIP_LINK
 # -fstack-reuse=none for all gcc builds. (Only gcc understands this flag).
 try_append_cxx_flags("-fstack-reuse=none" TARGET core_interface)
 
+find_package(Python3 3.9 COMPONENTS Interpreter)
+if(Python3_EXECUTABLE)
+  set(PYTHON_COMMAND ${Python3_EXECUTABLE})
+else()
+  list(APPEND configure_warnings
+    "Minimum required Python not found. Utils and rpcauth tests are disabled."
+  )
+endif()
+
 if(BUILD_TESTS)
   enable_testing()
 endif()
@@ -362,11 +371,15 @@ endif()
 # - https://github.com/bitcoin/bitcoin/pull/30312#issuecomment-2191235833
 set(CMAKE_SKIP_BUILD_RPATH TRUE)
 set(CMAKE_SKIP_INSTALL_RPATH TRUE)
+add_subdirectory(test)
+
 include(cmake/crc32c.cmake)
 include(cmake/leveldb.cmake)
 include(cmake/minisketch.cmake)
 add_subdirectory(src)
 
+include(cmake/tests.cmake)
+
 message("\n")
 message("Configure summary")
 message("=================")
diff --git a/cmake/tests.cmake b/cmake/tests.cmake
new file mode 100644
index 00000000000..27913298001
--- /dev/null
+++ b/cmake/tests.cmake
@@ -0,0 +1,15 @@
+# Copyright (c) 2023-present The Bitcoin Core developers
+# Distributed under the MIT software license, see the accompanying
+# file COPYING or https://opensource.org/license/mit/.
+
+if(TARGET bitcoin-util AND TARGET bitcoin-tx AND PYTHON_COMMAND)
+  add_test(NAME util_test_runner
+    COMMAND ${CMAKE_COMMAND} -E env BITCOINUTIL=$<TARGET_FILE:bitcoin-util> BITCOINTX=$<TARGET_FILE:bitcoin-tx> ${PYTHON_COMMAND} ${PROJECT_BINARY_DIR}/test/util/test_runner.py
+  )
+endif()
+
+if(PYTHON_COMMAND)
+  add_test(NAME util_rpcauth_test
+    COMMAND ${PYTHON_COMMAND} ${PROJECT_BINARY_DIR}/test/util/rpcauth-test.py
+  )
+endif()
diff --git a/test/CMakeLists.txt b/test/CMakeLists.txt
new file mode 100644
index 00000000000..9fd4e6e84ea
--- /dev/null
+++ b/test/CMakeLists.txt
@@ -0,0 +1,48 @@
+# Copyright (c) 2023-present The Bitcoin Core developers
+# Distributed under the MIT software license, see the accompanying
+# file COPYING or https://opensource.org/license/mit/.
+
+function(create_test_config)
+  set(abs_top_srcdir ${PROJECT_SOURCE_DIR})
+  set(abs_top_builddir ${PROJECT_BINARY_DIR})
+  set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
+
+  macro(set_configure_variable var conf_var)
+    if(${var})
+      set(${conf_var}_TRUE "")
+    else()
+      set(${conf_var}_TRUE "#")
+    endif()
+  endmacro()
+
+  set_configure_variable(ENABLE_WALLET ENABLE_WALLET)
+  set_configure_variable(WITH_SQLITE USE_SQLITE)
+  set_configure_variable(WITH_BDB USE_BDB)
+  set_configure_variable(BUILD_CLI BUILD_BITCOIN_CLI)
+  set_configure_variable(BUILD_UTIL BUILD_BITCOIN_UTIL)
+  set_configure_variable(BUILD_WALLET_TOOL BUILD_BITCOIN_WALLET)
+  set_configure_variable(BUILD_DAEMON BUILD_BITCOIND)
+  set_configure_variable(BUILD_FUZZ_BINARY ENABLE_FUZZ_BINARY)
+  set_configure_variable(WITH_ZMQ ENABLE_ZMQ)
+  set_configure_variable(ENABLE_EXTERNAL_SIGNER ENABLE_EXTERNAL_SIGNER)
+  set_configure_variable(WITH_USDT ENABLE_USDT_TRACEPOINTS)
+
+  configure_file(config.ini.in config.ini @ONLY)
+endfunction()
+
+create_test_config()
+
+file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/functional)
+file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/fuzz)
+file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/util)
+
+file(GLOB_RECURSE functional_tests RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} functional/*)
+foreach(script ${functional_tests} fuzz/test_runner.py util/rpcauth-test.py util/test_runner.py)
+  if(CMAKE_HOST_WIN32)
+    set(symlink)
+  else()
+    set(symlink SYMBOLIC)
+  endif()
+  file(CREATE_LINK ${CMAKE_CURRENT_SOURCE_DIR}/${script} ${CMAKE_CURRENT_BINARY_DIR}/${script} COPY_ON_ERROR ${symlink})
+endforeach()
+unset(functional_tests)
diff --git a/test/functional/test_runner.py b/test/functional/test_runner.py
index b85bf1c668f..59c37aa18f4 100755
--- a/test/functional/test_runner.py
+++ b/test/functional/test_runner.py
@@ -595,7 +595,7 @@ def run_tests(*, test_list, src_dir, build_dir, tmpdir, jobs=1, enable_coverage=
         print(f"{BOLD[1]}WARNING!{BOLD[0]} There may be insufficient free space in {tmpdir} to run the Bitcoin functional test suite. "
               f"Running the test suite with fewer than {min_space // (1024 * 1024)} MB of free space might cause tests to fail.")
 
-    tests_dir = src_dir + '/test/functional/'
+    tests_dir = build_dir + '/test/functional/'
     # This allows `test_runner.py` to work from an out-of-source build directory using a symlink,
     # a hard link or a copy on any platform. See https://github.com/bitcoin/bitcoin/pull/27561.
     sys.path.append(tests_dir)